blob: f67d89194a51db876ad615f99400a7c215706f3f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
|
<?xml version="1.0" encoding="utf-8" standalone="yes" ?>
<!--
* This file is part of the LibreOffice project.
*
* This Source Code Form is subject to the terms of the Mozilla Public
* License, v. 2.0. If a copy of the MPL was not distributed with this
* file, You can obtain one at http://mozilla.org/MPL/2.0/.
*
* This file incorporates work covered by the following license notice:
*
* Licensed to the Apache Software Foundation (ASF) under one or more
* contributor license agreements. See the NOTICE file distributed
* with this work for additional information regarding copyright
* ownership. The ASF licenses this file to you under the Apache
* License, Version 2.0 (the "License"); you may not use this file
* except in compliance with the License. You may obtain a copy of
* the License at http://www.apache.org/licenses/LICENSE-2.0 .
-->
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:oor="http://openoffice.org/2001/registry"
version="1.0">
<xsl:param name="LIBO_SHARE_FOLDER"/>
<xsl:param name="LIBO_SHARE_HELP_FOLDER"/>
<!-- Get the correct format -->
<xsl:output method="xml" indent="yes"/>
<xsl:namespace-alias stylesheet-prefix="xs" result-prefix="xs"></xsl:namespace-alias>
<!-- Remove all comments from the schema files -->
<xsl:template match="*|@*">
<xsl:copy>
<xsl:apply-templates select="*|@*"/>
</xsl:copy>
</xsl:template>
<!-- suppress the location of the schema -->
<xsl:template match = "@xsi:schemaLocation"/>
<!-- suppress the constraints of the schema
<xsl:template match = "constraints"/> -->
<!-- suppress all documentation items
<xsl:template match = "info"/> -->
<!-- suppress constraints for deprecated items -->
<xsl:template match = "constraints[../info/deprecated]"/>
<!-- suppress all documentation for deprecated items -->
<xsl:template match = "desc[../deprecated]"/>
<xsl:template match = "label[../deprecated]"/>
<!-- copy all other documentation with content -->
<xsl:template match="desc|label">
<xsl:copy>
<xsl:apply-templates select="@*"/>
<xsl:value-of select="."/>
</xsl:copy>
</xsl:template>
<!-- suppress all author items -->
<xsl:template match = "author"/>
<!-- suppress values, which are marked as nil -->
<xsl:template match="value[@xsi:nil='true']" />
<!-- copy all other values with content -->
<xsl:template match="value">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match ="it|unicode">
<xsl:copy>
<xsl:apply-templates select = "@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="text()">
<xsl:call-template name="replacetwo">
<xsl:with-param name="input" select="current()"/>
<xsl:with-param name="pattern1" select="'@LIBO_SHARE_FOLDER@'"/>
<xsl:with-param name="replace1" select="$LIBO_SHARE_FOLDER"/>
<xsl:with-param name="pattern2" select="'@LIBO_SHARE_HELP_FOLDER@'"/>
<xsl:with-param name="replace2" select="$LIBO_SHARE_HELP_FOLDER"/>
</xsl:call-template>
</xsl:template>
<xsl:template name="replace">
<xsl:param name="input"/>
<xsl:param name="pattern"/>
<xsl:param name="replace"/>
<xsl:choose>
<xsl:when test="contains($input, $pattern)">
<xsl:value-of select="substring-before($input, $pattern)"/>
<xsl:value-of select="$replace"/>
<xsl:call-template name="replace">
<xsl:with-param
name="input" select="substring-after($input, $pattern)"/>
<xsl:with-param name="pattern" select="$pattern"/>
<xsl:with-param name="replace" select="$replace"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$input"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="replacetwo">
<xsl:param name="input"/>
<xsl:param name="pattern1"/>
<xsl:param name="replace1"/>
<xsl:param name="pattern2"/>
<xsl:param name="replace2"/>
<xsl:choose>
<xsl:when test="contains($input, $pattern1)">
<xsl:call-template name="replace">
<xsl:with-param
name="input" select="substring-before($input, $pattern1)"/>
<xsl:with-param name="pattern" select="$pattern2"/>
<xsl:with-param name="replace" select="$replace2"/>
</xsl:call-template>
<xsl:value-of select="$replace1"/>
<xsl:call-template name="replacetwo">
<xsl:with-param
name="input" select="substring-after($input, $pattern1)"/>
<xsl:with-param name="pattern1" select="$pattern1"/>
<xsl:with-param name="replace1" select="$replace1"/>
<xsl:with-param name="pattern2" select="$pattern2"/>
<xsl:with-param name="replace2" select="$replace2"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:call-template name="replace">
<xsl:with-param
name="input" select="$input"/>
<xsl:with-param name="pattern" select="$pattern2"/>
<xsl:with-param name="replace" select="$replace2"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:transform>
|
