1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
|
%{
/*
* lexer for parsing ressource source files (*.src)
*
*/
/* enlarge token buffer to tokenize whole strings */
#undef YYLMAX
#define YYLMAX 64000
/* to enable debug output define LEXDEBUG */
#define LEXDEBUG 1
#ifdef LEXDEBUG
#define OUTPUT fprintf
#else
#define OUTPUT(Par1,Par2);
#endif
/* table of possible token ids */
#include "tokens.h"
#include <stdlib.h>
#include <stdio.h>
/* external functions (C++ code, declared as extren "C" */
extern WorkOnTokenSet( int, char* );
extern InitExport( char * , char * );
extern Parse( int nTyp, char *pTokenText );
extern EndExport();
extern SetError();
extern GetError();
extern char *GetOutputFile( int argc, char* argv[]);
extern FILE *GetNextFile();
extern int isQuiet();
/* forwards */
void YYWarning();
%}
%p 24000
%e 1200
%n 500
%%
^[\t ]*"#pragma".* {
WorkOnTokenSet( PRAGMA, yytext );
}
^[ \t]*\n {
WorkOnTokenSet( EMPTYLINE, yytext );
}
[\t ]+ |
^[\t ]*"#include".* |
^[\t ]*"#undef".* |
"//".* |
";" |
"<" |
">" |
\n {
WorkOnTokenSet( IGNOREDTOKENS, yytext );
}
"/*" {
char c1 = 0, c2 = input();
char pChar[2];
pChar[1] = 0x00;
pChar[0] = c2;
WorkOnTokenSet( COMMEND, yytext );
WorkOnTokenSet( COMMEND, pChar );
for(;;) {
if ( c2 == EOF )
break;
if ( c1 == '*' && c2 == '/' )
break;
c1 = c2;
c2 = input();
pChar[0] = c2;
WorkOnTokenSet( COMMEND, pChar );
}
}
(^[\t ]*"#ifndef".+$) |
(^[\t ]*"#ifdef".+$) |
(^[\t ]*"#if".+$) |
(^[\t ]*"#elif".*$) |
(^[\t ]*"#else".*$) |
(^[\t ]*"#endif".*$) {
WorkOnTokenSet( CONDITION, yytext );
}
[a-zA-Z]+[\t ]+[^={\n]+[\t ] {
/* defined Res */
WorkOnTokenSet( DEFINEDRES, yytext );
}
[a-zA-Z]+[ \t]+[^={;\n]+\n[ \t]*"#".*\n[ \t]*"{" |
[a-zA-Z]+[ \t]+[^={;\n]+\n?([ \t]*"//".*\n)*[ \t]*"{" {
/* RESSOURCE // String TTT_XX ... */
WorkOnTokenSet( RESSOURCE, yytext );
}
^[\t ]*[a-zA-Z_]+[\t ]*"\\"?[\t ]*\n?[ \t]*"{"[\t ]*"\\"? {
/* SMALRESSOURCE // String ... */
WorkOnTokenSet( SMALRESSOURCE, yytext );
}
[\t ]*[a-zA-Z0-9_]+[ \t]*("["[ \t]*[a-zA-Z0-9_\-]+[ \t]*"]"[ \t]*)?=[ \t]*L?\".*\".*\n? {
/* TEXTLINE // TextTyp = "A Text" */
WorkOnTokenSet( TEXTLINE, yytext );
}
[\t ]*[a-zA-Z0-9_]+[ \t]*("["[ \t]*[a-zA-Z0-9_\-]+[ \t]*"]"[ \t]*)?(\n[ \t]*)?=([ \t]*\n)?(([a-zA-Z0-9_]+)|(\".*\")|([ \t\n]*))*\".*\"(([a-zA-Z0-9_]+)|(\".*\")|([ \t\n]*))*; {
/* LONGTEXTLINE // TextTyp = "A Text" HHH_XXX "A Text" ZZZ_TTT ... */
WorkOnTokenSet( LONGTEXTLINE, yytext );
}
\".*\" {
/* TEXT // "A Text" */
WorkOnTokenSet( TEXT, yytext );
}
"{"[ \t]*\\? {
/* LEVELUP */
WorkOnTokenSet( LEVELUP, yytext );
}
"}"[ \t]*;([ \t]*\\)? {
/* LEVELDOWN */
WorkOnTokenSet( LEVELDOWN, yytext );
}
[a-zA-Z0-9_]+[ \t]*"="[ \t]*"MAP_APPFONT"[ \t]*"(".+")".* {
/* APPFONTMAPPING Typ = MAP_APPFONT( ... ) */
WorkOnTokenSet( APPFONTMAPPING, yytext );
}
[ \t]*[a-zA-Z0-9_]+[ \t]*=[ \t]*[0123456789]{1,5}[ \t]*";"?\\? {
/* TEXTREFID // TextTyp = 12345 */
WorkOnTokenSet( TEXTREFID, yytext );
}
[a-zA-Z0-9_]+[ \t]*"="[\t ]*([ \t]*"//".*\n)*.* |
[a-zA-Z0-9_]+[ \t]*"=".* {
/* ASSIGNMENT Typ = ... */
WorkOnTokenSet( ASSIGNMENT, yytext );
}
[a-zA-Z0-9_]+[ \t]*("["[ \t]*[a-zA-Z0-9_\-]+[ \t]*"]"[ \t]*)?"="[ \t]*(\\[ \t]*)?\n?[ \t]*"{"[ \t]*(\\[ \t]*)?\n?[ \t]*"<" {
/* LISTASSIGNMENT Typ [ ... ] = ... */
WorkOnTokenSet( LISTASSIGNMENT, yytext );
}
"StringList"+[ \t]*("["[ \t]*[a-zA-Z0-9_\-]+[ \t]*"]"[ \t]*)?"="[ \t]*(\\[ \t]*)?\n?[ \t]*"{"[ \t]*(\\[ \t]*)?\n?[ \t]* {
/* LISTASSIGNMENT Typ [ ... ] = ... */
WorkOnTokenSet( LISTASSIGNMENT, yytext );
}
"UIEntries"[ \t]*("["[ \t]*[a-zA-Z0-9_\-]+[ \t]*"]"[ \t]*)?"="[ \t]*(\\[ \t]*)?\n?[ \t]*"{" {
/* UIENTRIES */
WorkOnTokenSet( UIENTRIES, yytext );
}
"<"?[ \t]*L?\".*\".*">" {
/* LISTTEXT */
WorkOnTokenSet( LISTTEXT, yytext );
}
[ \t]*"#define"[ \t]+[a-zA-Z0-9_]+.*"\\" {
/* RSCDEFINE #define ... */
WorkOnTokenSet( RSCDEFINE, yytext );
}
[ \t]*"#define"[ \t]+[a-zA-Z0-9_]+.+ {
/* #define ... */
WorkOnTokenSet( NORMDEFINE, yytext );
}
"\\" {
/* RSCDEFINELEND */
WorkOnTokenSet( RSCDEFINELEND, yytext );
}
[a-zA-Z0-9_]+[ \t]*; {
/* allowed other tokens like "49 ;" or "SFX_... ;" */
WorkOnTokenSet( ANYTOKEN, yytext );
}
. {
WorkOnTokenSet( UNKNOWNCHAR, yytext );
/* YYWarning( "Unknown Char" ); */
}
"{"?[ \t]*\".*\"[ \t]*";"[ \t]*"}" {
/* _LISTTEXT */
WorkOnTokenSet( _LISTTEXT, yytext );
}
%%
/*****************************************************************************/
int yywrap(void)
/*****************************************************************************/
{
FILE *pFile;
pFile = GetNextFile();
if ( pFile ) {
yyin = pFile;
yylineno = 0;
return 0;
}
/* end of input reached */
return 1;
}
/*****************************************************************************/
void YYWarning( char *s )
/*****************************************************************************/
{
/* write warning to stderr */
fprintf( stderr, "Warning: \"%s\" in line %d: \"%s\"\n", s, yylineno, yytext );
}
/*****************************************************************************/
void yyerror( char *s )
/*****************************************************************************/
{
/* write error to stderr */
fprintf( stderr, "Error: \"%s\" in line %d: \"%s\"\n", s, yylineno, yytext );
SetError();
}
/*****************************************************************************/
int
#ifdef WNT
_cdecl
#endif
main( int argc, char* argv[])
/*****************************************************************************/
{
/* error level */
int nRetValue = 0;
char *pOutput;
FILE *pFile;
pOutput = GetOutputFile( argc, argv );
if( !isQuiet() ){
fprintf( stdout, "\nTransEx 3.1 Copyright 2000 Sun Microsystems, Inc. All Rights Reserved.\n" );
fprintf( stdout, "========================================================================\n" );
}
if ( !pOutput ) {
fprintf( stdout, "Syntax:TRANSEX[-p Prj][-r PrjRoot]-i FileIn...[-o FileOut][-m DataBase][-e][-b][-u][-L l1,l2,...]\n" );
fprintf( stdout, " Prj: Project\n" );
fprintf( stdout, " PrjRoot: Path to project root (..\\.. etc.)\n" );
fprintf( stdout, " FileIn: Source files (*.src)\n" );
fprintf( stdout, " FileOut: Destination file (*.*)\n" );
fprintf( stdout, " DataBase: Mergedata (*.sdf)\n" );
fprintf( stdout, " -QQ: quiet output\n" );
fprintf( stdout, " -e: Disable writing errorlog\n" );
fprintf( stdout, " -b: Break when Token \"HelpText\" found in source\n" );
fprintf( stdout, " -u: [english] and [german] are allowed, Id is Taken from DataBase \n" );
fprintf( stdout, " -NOUTF8: disable UTF8 as language independent encoding\n" );
fprintf( stdout, " -L: Restrict the handled languages. l1,l2,... are elements of (de,en-US...)\n" );
fprintf( stdout, " A fallback language can be defined like this: l1=f1.\n" );
fprintf( stdout, " f1, f2,... are also elements of (de,en-US...)\n" );
fprintf( stdout, " Example: -L de,es=en-US\n" );
fprintf( stdout, " Restriction to de and es, en-US will be fallback for es\n" );
return 1;
}
pFile = GetNextFile();
if ( !pFile )
return 1;
yyin = pFile;
/* create global instance of class Export */
InitExport( pOutput , pFile );
/* start parser */
yylex();
Close();
/* get error info. and end export */
nRetValue = GetError();
EndExport();
if( !isQuiet() ) fprintf( stdout, "\n===================================\n\n" );
/* return error level */
return nRetValue;
}
|